<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
					   xmlns:s="library://ns.adobe.com/flex/spark" 
					   xmlns:mx="library://ns.adobe.com/flex/mx"
					   minWidth="600" minHeight="600"
					   creationComplete="application1_creationCompleteHandler(event)">
	<fx:Script>
		<![CDATA[
			import com.phidgets.PhidgetAdvancedServo;
			import com.phidgets.events.PhidgetEvent;
			
			import mx.controls.Alert;
			import mx.events.FlexEvent;
			
			private var socket:ServerSocket;
			private var incomingSocket:Socket;
			private var phidget:PhidgetAdvancedServo;
			
			protected function application1_creationCompleteHandler(event:FlexEvent):void
			{
				phidget = new PhidgetAdvancedServo();
				phidget.addEventListener(PhidgetEvent.CONNECT, onConnect);
				phidget.addEventListener(PhidgetEvent.ATTACH, onAttach);
				
				phidget.open("localhost", 5001);
			}
					
			private function onConnect(event:PhidgetEvent):void {
				Alert.show("Connected");
			}
			
			private function onAttach(event:PhidgetEvent):void {
				Alert.show("Attached: setting initial position");
				phidget.setPosition(0, 90);
				phidget.setPosition(1, 90);
				phidget.setPosition(4, 90);
				phidget.setPosition(5, 90);
				
				socket = new ServerSocket();
				socket.addEventListener(ServerSocketConnectEvent.CONNECT, onSocketConnect);
				socket.bind(5555);
				socket.listen();
			}
			
			private function onSocketConnect(evt:ServerSocketConnectEvent):void {
				if(!incomingSocket) {
					incomingSocket = evt.socket as Socket;
				}
				incomingSocket.addEventListener(ProgressEvent.SOCKET_DATA, onSocketData);
				incomingSocket.addEventListener(Event.CLOSE, onSocketClosed);
			}
			
			private function onSocketClosed(evt:Event):void {
				incomingSocket = null;
			}
			
			private function onSocketData(evt:ProgressEvent):void {
				try {
					var output:String = incomingSocket.readUTFBytes(incomingSocket.bytesAvailable);
					var values:Array = output.split(",");
					
					// Getting the orientation values
					var xValue:Number = Number(values[0]);
					var yValue:Number = Number(values[1]);	
					var zValue:Number = Number(values[2]);	
					
					// The orientation values lie between -1 and 1
					// Servos are in the middle by default, which means
					// turning one for 90 degrees will trigger the
					// opposite one to turn 90 degrees in the other direction.
					var pos0:Number = Math.round((xValue * 90) + 90);
					var pos1:Number = Math.round((-xValue * 90) + 90);
					var pos4:Number = Math.round((yValue * 90) + 90);
					var pos5:Number = Math.round((-yValue * 90) + 90);
					phidget.setPosition(0, pos0); // x = 1 => rotation 180
					phidget.setPosition(1, pos1); // x = 1 => rotation 0
					phidget.setPosition(4, pos4); // y = -1 => rotation 0
					phidget.setPosition(5, pos5); // y = -1 => rotation 180
					log.text = "pos0 = " + pos0 + "; pos1 = " + pos1 
						+ "; pos4 = " + pos4 + "; pos5 = " + pos5
						+ "\n" + log.text;
				} catch(e:Error) {}
			}

		]]>
	</fx:Script>
	
	<s:TextArea id="log" width="100%" height="100%"/>
	
</s:WindowedApplication>